全文约1100字
大家好，我是古老师。今天我将发布2025年第8周PMC生产计划群的“每日一练”题目与答案。本次发布的资料包括每日练习题、对应的正确答案以及对相关考点的详细解析，旨在辅助大家的学习，并作为参考资料使用。
本周的主题集中在PMC工作场景中的逻辑判断，包含订单交期判断、补货判断、优先级判断、设备负荷预警，供应商等级判断等，这些判断通过布尔逻辑公式（IF/AND/OR) 可以快速的建立模型，同时也能提高PMC的逻辑能力。
周一： 订单交期判断题目背景：
订单交期的规则一般以下：
1. 若交货日期 > 截止日期 → 计算延迟天数 = 交货日期 - 截止日期
2. 延迟天数 > 3 → "严重延迟"
3. 延迟天数 > 0 且 ≤3 → "一般延迟"
4. 否则 → "正常"
有了这些明确的规则后就可以用判断函数进行判断了。
考核点：
1. IFS函数
2. LET 函数
3. HSTACK 函数
参考答案：
=LET(A,TRIMRANGE(D2:D1000)-TRIMRANGE(E2:E1000),HSTACK(A,IFS(A>3,"严重延迟",A>0,"一般延迟",A<=0,"正常")))
周二： 触发补货申请的条件题目背景：
在工厂中进行物料采购时，会制定一些规则进行被货,如下： 1. 安全库存 = 0 → 无论库存是否低于安全库存，必须补货
2. 否则 当前库存 < 安全库存 且 当前库存 < 最小起订量 → 补货
3. 其他情况 → 不补货
此时可以配合AND等函数进行多条件判断
考核点：
1. IF函数
2. 裁剪函数、LET函数等；
参考答案1：
E2=LET(A,TRIMRANGE(B2:B12),B,TRIMRANGE(C2:C12),C,TRIMRANGE(D2:D12),IF(A=0,"补货",IF((B<A)*(B<C),"补货","不补货")))
参考答案2：
周三： 订单优先级判定题目背景：
在编制生产计划中，订单的紧急程度一定要有约束规则，不然就会陷入一个订单混乱的局面，什么订单都是紧急的，例如以下规则： 1.类型为"紧急" 或 重要性为"高" → A
2.类型为"加急" → B
3.其他 → C
考核点：
1. 异常的判定
2. 相关函数：LET/IFNA
参考答案：
填充公式：
=IFNA(IFS(AND(C2="紧急",D2="高"),"A+",OR(C2="紧急",D2="高"),"A",C2="加急","B"),"C")
数组公式：
=LET(C,TRIMRANGE(C2:C100),H,OFFSET(C,,1)=D2,G,C=C2,IF(G*H,"A+",IF(G+H>0,"A",IF(C=C4,"B","C"))))
周四： 设备负荷预警判断题目背景：
除了最订单紧急的判断，还有设备预警，这也是要订单评审的一个重要节点，例如以下规则：
1.产线类型为L1/L2：需同时满足以下条件→标记超负荷
2.实际产量>(理论产能×0.9)
3.设备运行时间>(理论产能×0.8)
考核点：
1. 多条件判断
2. 动态数组自动扩展
参考答案1
填充公式：
=IF(OR(AND(A2="L1",C2>B2*0.9,D2>B2*0.8),AND(A2="L2",C2>B2*0.9,D2>B2*0.8),AND(A2="L3",C2>B2*0.85)),"是","否")
参考答案2：
E2=LET(x,TRIMRANGE(C2:C99),l,OFFSET(x,,-1),IF(OFFSET(x,,-2)=A4,IF(x>l*0.85,"是","否"),IF((x>l*0.9)*(OFFSET(x,,1)>l*0.8),"是","否")))
周五：供应商交付等级判断题目背景：
在生产计划管理中，对供应商考核是非常重要的一个环节，制定一个供应商考核方案是有效评定供应商等级的有效方法，如以下规则： 交货准时率 ≥ 95% 且 订单量 ≥ 1000 → S级
交货准时率 ≥ 90% 且 订单量 ≥ 800 → A级
交货准时率 ≥ 85% → B级
其他 → C级
考核点：
1. IF 函数判断
2. 动态数组自动扩展
参考答案1：
填充公式：
=LET(B,B2,D,C2/B,HSTACK(D,IF(AND(D>=0.95,B>=1000),"S级",IF(AND(D>=0.9,B>=800),"A级",IF(D>=0.85,"B级","C级")))))
数组公式带扩展
=LET(B,TRIMRANGE(B2:B99),C,OFFSET(B,,1),D,C/B,HSTACK(D,IF((D>95%)*(B>1000),"S级",IF((D>90%)*(B>800),"A级",IF(D>85%,"B级","C级")))))
以上就是本周关于PMC生产计划的所有题目和答案。希望通过这些练习，大家能够更好地理解PMC工作中的关键概念和计算方法，从而更加高效地处理实际工作中的各种需求。
同时，欢迎大家加入古哥PMC专业群，与更多的同行一起交流经验、共同学习、进步和成长。感谢大家的积极参与和支持！
